"                  ZI TRAVEL
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Interfaccia tabella travel'
define root view entity ZI_TRAVEL_ALRM as select from zcor_travel_alrm as Travel 
                 
    composition [0..*] of ZI_BOOk_ALRM as _Booking
    association [0..1] to /DMO/I_Agency as _Agency on $projection.AgencyID = _Agency.AgencyID
    association [0..1] to /DMO/I_Customer as _Customer on $projection.CustomerID = _Customer.CustomerID
    association [0..1] to I_Currency as _Currency on $projection.CurrencyCode = _Currency.Currency
                  
{

    key travel_uuid as TravelUUID,
    travel_id as TravelID,
    agency_id as AgencyID,
    customer_id as CustomerID,
    begin_date as BeginDate,
    end_date as EndDate,
    @Semantics.amount.currencyCode: 'CurrencyCode'
    booking_fee as BookingFee,
    @Semantics.amount.currencyCode: 'CurrencyCode'
    total_price as TotalPrice,
    currency_code as CurrencyCode,
    description as Description,
    overall_status as OverallStatus,
    @Semantics.user.createdBy : true
    created_by as CreatedBy,
    @Semantics.systemDateTime.createdAt : true
    created_at as CreatedAt,
    @Semantics.systemDateTime.lastChangedAt: true
    last_changed_at as LastChangedAt,
    @Semantics.user.lastChangedBy: true
    last_changed_by as LastChangedBy,
    @Semantics.systemDateTime.localInstanceLastChangedAt: true
    local_last_changed_at as LocalLastChangedAt,
    
    _Booking,
    _Agency,
    _Customer,
    _Currency
}


"      ZI BOOKING
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Interfaccia tabella book'
define view entity ZI_BOOk_ALRM
  as select from zcor_book_alrm as Booking

  association to parent ZI_TRAVEL_ALRM    as _Travel     on  $projection.TravelUUID = _Travel.TravelUuid
  association [1..1] to /DMO/I_Customer   as _Customer   on  $projection.CustomerID = _Customer.CustomerID
  association [1..1] to /DMO/I_Carrier    as _Carrier    on  $projection.CarrierID = _Carrier.AirlineID

  association [1..1] to /DMO/I_Connection as _Connection on  $projection.ConnectionID = _Connection.ConnectionID
                                                         and $projection.CarrierID    = _Connection.AirlineID



  association [1..1] to /DMO/I_Flight     as _Flight     on  $projection.FlightDate   = _Flight.FlightDate
                                                         and $projection.CarrierID    = _Flight.AirlineID
                                                         and $projection.ConnectionID = _Flight.ConnectionID



  association [0..1] to I_Currency        as _Currency   on  $projection.CurrencyCode = _Currency.Currency

{
  key booking_uuid          as BookingUUID,
      travel_uuid           as TravelUUID,
      booking_id            as BookingID,
      booking_date          as BookingDate,
      customer_id           as CustomerID,
      carrier_id            as CarrierID,
      connection_id         as ConnectionID,
      flight_date           as FlightDate,
      @Semantics.amount.currencyCode: 'CurrencyCode'
      flight_price          as FlightPrice,
      currency_code         as CurrencyCode,
      @Semantics.user.createdBy: true
      created_by            as CreatedBy,
      @Semantics.user.lastChangedBy: true
      last_changed_by       as LastChangedBy,
      @Semantics.systemDateTime.localInstanceLastChangedAt: true
      local_last_changed_at as LocalLastChangedAt,
      
      
    _Travel,
    _Connection,
    _Customer,
    _Currency,
    _Flight,
    _Carrier
}