sysuse auto, clear
sum price 
local price_mean = r(mean)
sum mpg
local mpg_mean = r(mean)

**************************** Code replicating margins atmeans
logit foreign price mpg
local delta = .1
local p1 = 1/(1 + exp( - ( _b[_cons] + _b[price]*`price_mean' + _b[mpg]*`mpg_mean')          ))
local p2 = 1/(1 + exp( - ( _b[_cons] + _b[price]*`price_mean' + _b[mpg]*(`mpg_mean'+`delta'))))

di "Derivative of foreign wrt mpg calculated by hand at means: " (`p2' - `p1')/`delta'
margins, dydx(mpg) atmeans

**************************** Code replicating margins at specific value
logit foreign price mpg
local p1 = 1/(1 + exp( - ( _b[_cons] + _b[price]*1000 + _b[mpg]*20)          ))
local p2 = 1/(1 + exp( - ( _b[_cons] + _b[price]*1000 + _b[mpg]*(20+`delta'))))

di "Derivative of foreign wrt mpg calculated by hand at mpg=20 and price=1000: " (`p2' - `p1')/`delta'
margins, dydx(mpg) at(mpg=20 price=1000)

**************************** Code replicating average marginal effect
keep if _n==1
local delta = .000001

local price1 = price[1]
local mpg1 = mpg[1]
local p1 = 1/(1 + exp( - ( _b[_cons] + _b[price]*`price1' + _b[mpg]*`mpg1')          ))
local p2 = 1/(1 + exp( - ( _b[_cons] + _b[price]*`price1' + _b[mpg]*(`mpg1'+`delta'))))
di "Derivative of foreign wrt mpg calculated by hand at first observation: " (`p2' - `p1')/`delta'
margins, dydx(mpg)